The Walker Function

Mikhail D. Mikhailov
Atila P. Silva Freire

The special function Ξ(η) (the Walker function) and its derivatives are important for the description of near-wall turbulent flows. This article gives exact expressions for these functions, based on original identities for the hypergeometric functions (Subscript[, 1])(Subscript[F, 1]) and (Subscript[, p ])(Subscript[F, p]). We also introduce a new initial value problem that generates interpolating functions for Ξ(η) and its derivatives.

Introduction

The quantitative description of turbulent flows is known to be severely hampered by the extremely rapid variations in the mean and higher-order statistics in the near-wall region. Some very early studies [, , ] showed that the basic structure of an attached turbulent boundary layer consists of a viscous wall layer, in which the turbulent and laminar stresses are of comparable magnitude, and a defect layer, in which the velocity profile may be expressed in terms of a small perturbation to the external flow solution []. Also, [, , ] showed that this structure naturally leads to a universal velocity solution that has logarithmic behavior and depends on the velocity and length scales based on the friction velocity.

For separated flows, this picture changes dramatically; the friction velocity reduces to zero, so that a new scaling procedure based on the local pressure gradient at the wall needs to be introduced. The logarithmic solution is then reduced to a square-root velocity profile. Aspects of the complex flow structure due to separation are thoroughly discussed in [].

To incorporate the structure of organized motion into a near-wall analytical model, Walker et al. [] proposed a time-dependent formulation based on the dynamical features of the wall layer. Following the general description commonly found in the literature, the flow dynamics are considered to be dominated by two features: wall layer streaks and the bursting phenomenon. The streaks are elongated in the flow direction, with length of the order of 1000(SuperPlus[δ]) (where (SuperPlus[δ])=ν/(SuperStar[u]), ν is the kinematic viscosity, and (SuperStar[u]) is the friction velocity), and can be observed over a large characteristic time, the quiescent period [].

Analytical near-wall solutions for turbulent flows are of central significance, since the extreme thinness of the viscous sublayer naturally demands the use of exceptionally fine meshes in the numerical computation of problems of practical relevance. This difficulty can be naturally overcome, provided the local analytical solutions are used to bridge the viscous-dominated region.

In [], the duration of the quiescent period is assumed to be much larger than the duration of the bursting process, so that solutions for the unsteady Navier–Stokes equations can be given in terms of the flow development between pairs of streaks. The analysis resorts to standard methods for orthogonal functions to arrive at a set of three nonlinear governing equations that have to be solved numerically. In addition, a semi-similarity procedure is proposed, resulting in a solution that includes Ξ(η). This function is a similarity solution of the linear diffusion equation that behaves logarithmically for large η and vanishes at η=0. Mean velocity profiles are obtained by evaluating a time-average of the solution over the period between bursts, (Subscript[T, B]^(+)).

In mathematics Ξ is generally used to denote a variant of the Riemann zeta function. Here, no confusion should arise: the function Ξ, as defined in [], is given by the equation e1 below.

Instantaneous and averaged velocity profiles are presented for four combinations of (SuperPlus[p]) (the dimensionless pressure gradient parameter) and (Subscript[T, B]^(+)) in accordance with typically measured values. For constant pressure flow ((SuperPlus[p])=0., (Subscript[T, B]^(+))=110.2), the canonical boundary layer structure is well reproduced. Under a favorable pressure gradient ((SuperPlus[p])=-0.098, (Subscript[T, B]^(+))=164), the instantaneous profiles are accelerated as expected. For adverse pressure gradients ((SuperPlus[p])=0.11, (Subscript[T, B]^(+))=29.8; (SuperPlus[p])=0.5, (Subscript[T, B]^(+))=25), (Subscript[T, B]^(+)) decreases and, for the latter case, reverse instantaneous flow is observed over the latter part of the cycle.

Here, we develop a new version of the near-wall turbulent velocity profile shown in [], in particular, of the Ξ(η) function. This article introduces the required features of function Ξ(η) and its derivatives. In addition, we present some original identities for the hypergeometric functions (Subscript[, 1])(Subscript[F, 1]) and (Subscript[, p])(Subscript[F, p]).

Identity Involving (Subscript[, 1])(Subscript[F, 1]) and (Subscript[, p])(Subscript[F, p])

The function Ξ(η) is of particular relevance, being the only known similarity solution of the linear diffusion equation that behaves logarithmically for large η and vanishes at η=0 [].

The Ξ(η) function can be defined either in terms of an expansion or an integral, as shown in [] (equations (44) and (42)). In the latter form, the triple integral can be rearranged to a single integral.

e1=Ξ[η]==((E^(-(η^2)))/4)(∑_(j=1)^∞) (((2^j) d[j](η^(2j+1)))/((2j+1)!!))==(∫_0^η)(∫_0^ξ)(∫_0^t) (E^(-(ξ^2)+(t^2)-(x^2)))\[DifferentialD]x\[DifferentialD]t\[DifferentialD]ξ

The coefficients d[j] are defined by a recurrence relation.

e2={d[j]==d[j-1]+1/j,d[1]==1};

The sum in e1 is uniformly convergent for all η. This is particularly useful in the evaluation of Ξ(η) for small to moderate values of η [].

This solves the recurrence equation.

e3=RSolve[e2,d[j],j][[1,1]]

FullSimplify shows that the coefficients d[j] are the harmonic numbers.

e4=FullSimplify[RSolve[e2,d[j],j][[1,1]]]

After substituting equation e4 into equation e1, the sum turns out to be a hypergeometric function.

e5=e1/.e4

This is the second term of e5.

e5[[2]]

This is difficult to calculate for large numerical values of η, because (e^(-(η^2))) is extremely small, while the hypergeometric function is extremely large. To remove (e^(-(η^2))) from e5[[2]], we use the following identity.

FullSimplify[e6=Hypergeometric1F1[α,γ,(η^2)]==(E^(η^2))Hypergeometric1F1[γ-α,γ,-(η^2)]]

Take the derivative of e6 with respect to α for α=1 and γ=3/2.

e7=Rule@@D[e6,α]/.{α->1,γ->3/2}

Use e7 to substitute into e5.

e8=e5/.e7

To verify that e8 is an identity, we evaluate its right-hand side for η=6/5 with 100 digits of precision.

Rest[e8]

N[%/. η->6/5,100]

For Ξ'[η] and Ξ''[η], Mathematica 8 gives the following.

e9=D[Drop[e8,-1],η]

e10=D[e9,η]

Mathematica 8 can evaluate e9 and e10 for numerical values of η. The following rule generates derivatives of order n that earlier versions of Mathematica can evaluate.

WalkerDerivative[x_,n_:0]:=
D[Ξ[x],{x,n}]==Expand[Simplify[PowerExpand[D[- x/4 Hypergeometric1F1[C,3/2,-x^2],{x,n},C]/.C->1/2]]]

For Ξ'[η] and Ξ''[η], the function WalkerDerivative gives the following.

e11=WalkerDerivative[η,1]

e12=WalkerDerivative[η,2]

To verify that the right-hand sides of e9 and e11 are equal and that the right-hand sides of e10 and e12 are equal, we evaluate them for η=6/5 with 100 digits of precision.

N[{Last[e9]==Last[e11],Last[e10]==Last[e12]}/. η->6/5,100]

Initial Value Problem

To derive the initial value problem for Ξ[η], we use e8 and its derivatives.

e13=Drop[e8,{2}]

e14=D[e13,η]

e15=Expand[D[e14,η]]

To obtain the desired initial value problem, we eliminate from e14 and e15 the hypergeometric function and replace η by 0 in e13 and e14.

e16=Prepend[{e13,e14}/.η->0,Equal@@Expand[Solve[Eliminate[{e14,e15},e14[[2,4]]],Ξ''[η]][[1,1]]]]

The resulting ordinary differential equation is equivalent to equations (40) and (41) in []. The condition Ξ[0]==0 is also given in []. However, the condition Ξ'[0]==0 is missing in [], where no attempt is made to obtain a numerical solution.

We plot the function Ξ[η] (blue) and its derivative Ξ'[η] (purple).

Manipulate[
Plot[Evaluate[{NWalker[x],NDWalker[x]}],{x,-10,10},Frame->True,PlotRange->All,Axes->False,FrameLabel->{"η",Row[{"Ξ(η), Ξ'(η)"}],
Style[Row[{"Ξ(",NumberForm[X,{10,3}],") = ",NumberForm[NWalker[X],{10,3}],", Ξ'(",NumberForm[X,{10,3}],") = ",NumberForm[NDWalker[X],{10,3}]}],12]},
Epilog->{Red,PointSize[.02],Point[{X,NWalker[X]}],Green,Point[{X,NDWalker[X]}]}],
{{X,0,"η"},-10,10,0.001,Appearance->"Labeled"},
Initialization:>{NWalker[x_]:=If[x<0,-NWal[-x],NWal[x]];NDWalker[x_]:=If[x<0,NDWal[-x],NDWal[x]];
{NWal,NDWal}=Map[Last,
First[NDSolve[{Z'[x]==Y[x],Y'[x]==Sqrt[Pi] Erf[x]/2-2 x Y[x],Z[0]==0,Y[0]==0},{Z,Y},{x,0,10}]]]},
ControlPlacement->Bottom]

Conclusion

Exact expressions for the Walker function Ξ(η) and its derivatives are obtained. From a computational point of view, an important result is the specification of the initial value problem, for it allows extremely fast interpolating functions to be generated. From a mathematical point of view, some new identities between the two hypergeometric functions (Subscript[, 1])(Subscript[F, 1]) and (Subscript[, p])(Subscript[F, p]) are presented. These identities were revealed by the built-in Mathematica functions RSolve, Sum, and FullSimplify. Of possible interest is the application of the techniques to discover new identities and to the problems described in the book by Petkovšek et al. [].

Acknowledgments

The first author is thankful to the Brazilian National Research Council (CNPq) and the Brazilian National Institute of Standards (INMETRO) for their financial support of this research through a CNPq Research Fellowship–Edital MCT/CNPq/Inmetro nº 059/2010–PROMETRO Processo Nº 563061/2010–3.

The second author is grateful to the Brazilian National Research Council (CNPq) for the award of a Research Fellowship (Grant No. 303982/2009–8). The work was financially supported by the Rio de Janeiro Research Foundation (FAPERJ) through Grant E–26/170.005/2008.

References

L. Prandtl, “Über die ausgebildete Turbulenz,” ZAMM: Journal of Applied Mathematics and Mechanics/Zeitschrift für Angewandte Mathematik und Mechanik, 5, 1925 pp. 136–139.

T. von Kármán, “Mechanische Aehnlichkeit und Turbulenz,” Proceedings of the Third International Congress for Applied Mechanics, Vol. 1, Stockholm, 1930 (C. W. Oseen and W. Weibull, eds.), Stockholm: AB. Sveriges Litografiska Tryckerier, 1931 pp. 79-93 (in German).

C. B. Millikan, “A Critical Discussion of Turbulent Flow in Channels and Circular Tubes,” Proceedings of the 5th International Congress for Applied Mechanics, Cambridge, MA, 1938, New York: Wiley, 1939 pp. 386–392.

J. B. R. Loureiro, A. P. Silva Freire, “Scaling of Turbulent Separating Flows,” International Journal of Engineering Science, 49(5), 2011 pp. 397–410. doi:10.1016/j.ijengsci.2010.12.001.

J. D. A. Walker, D. E. Abbott, R. K. Scharnhorst, and G. G. Weigand, “Wall-Layer Model for the Velocity Profile in Turbulent Flows,” American Institute of Aeronautics and Astronautics Journal, 27(2), 1989 pp. 140–149.

S. J. Kline, W. C. Reynolds, F. A. Schraub, and P. W. Rundstadler, “The Structure of Turbulent Boundary Layers,” Journal of Fluid Mechanics, 30(4), 1967 pp. 741–773. journals.cambridge.org/abstract_S0022112067001740.

M. Petkovšek, H. S. Wilf, D. Zeilberger, A=B, Wellesley, MA: A. K. Peters, 1996. www.math.upenn.edu/%7Ewilf/AeqB.html.