Clusters Produced by Placing Rhombic Triacontahedra at the Vertices of Polyhedra

Sándor Kabai, Szaniszló Bérczi, and Lajos Szilassi

In this article we explore possible clusters of rhombic triacontahedra (RTs), usually by connecting them face to face, which happens when they are placed at the vertices of certain polyhedra. The edge length of such polyhedra is set to be twice the distance of a face of an RT from the origin (about 2.7527). The clusters thus produced can be used to build further clusters using an RT and a rhombic hexecontahedron (RH), the logo of Wolfram|Alpha. We briefly look at other kinds of connections and produce new clusters from old by using matching polyhedra instead of RTs.

Rhombic Triacontahedra (RT) and Rhombic Hexecontahedron (RH)

Here are the RT and RH.

rt=PolyhedronData["RhombicTriacontahedron","Faces"];
rh=PolyhedronData["RhombicHexecontahedron","Faces"];
Graphics3D[rt,Boxed->False]

Graphics3D[rh,Boxed->False]

To find the possible candidate polyhedra, let us summarize the angles of face centers relative to the center of a single face of RT, as seen from the origin.

({{face, radians, degrees}, {1, 0, 0°}, {1, π, 180°}, {4, π/2, 90°}, {4, π/5, 36°}, {4, 2π/5, 72°}, {4, 3π/5, 108°}, {4, 4π/5, 154°}, {4, π/3, 60°}, {4, 2π/3, 120°}})

The dimensions applicable in the clusters can be determined on the basis of the relationship of the cube and RT. For instance, the cube edge is equal to the longer diagonal of the face of the RT (a golden rhombus), 2sin(arctan(1.618))=1.70129. The diagonal of the cube equals the distance between opposite threefold vertices of the RT.

Additional information for finding possible candidate polyhedra comes from a chart of truncations prepared by Szaniszló Bérczi. Figure  shows regular (Platonic) solids projected on a sphere. Archimedean solids are deduced from the regular solids by the truncation operation. A Platonic or Archimedean solid can be identified by its vertex configuration, because it is uniform; this is given by the Steiner symbol, which lists the faces that meet at a vertex. For example, (4,4,4) is the Steiner symbol for the cube, because three squares (4-sided faces) meet at each vertex. The RT-related structures should be arranged according to the third row of the table: (5,6,6), (3,5,3,5), (3,10,10), (5,5,5), (3,4,5,4), (4,6,10).

For more help, we can consider the relationship of RT to cube and to RH, on the basis of which all necessary dimensions can be calculated.

ϕ=GoldenRatio;
α=ArcTan[ϕ];
β=ArcTan[1/ϕ];
β1=ArcTan[1/ϕ^2];

This is the length of the cube edge.

ce=N[2Sin[α]]

This is the length of the cube diagonal, which is equal to the length of the threefold axis diagonal of the RT.

d3=ce Sqrt[3]

This is the face distance of the RT.

fd=ϕ ce

This is the length of the fivefold axis diagonal of the RT.

d5=Sqrt[ce^2+fd^2]

The relationship of the RT, cube, and a golden rectangle can be used to determine dimensions.

goldr=Rotate[Polygon[{{-ce/2,0,-ϕ ce/2},{ce/2,0,-ϕ ce/2},{ce/2,0,ϕ ce/2},{-ce/2,0,ϕ ce/2}}],-β,{0,1,0}];
cub=PolyhedronData["Cube","Faces"];
cubn=Rotate[Scale[cub,0.999 ce{1,1,1},{0,0,0}],-β,{0,1,0}];

Graphics3D[{{Opacity[0.2],rt},{Green,cubn},Yellow,goldr},SphericalRegion->True,Boxed->False,ViewPoint->{10,10,0},ViewAngle->0.07]

The relationship of the RT, RH, and a plane perpendicular to the threefold axis that cuts the RT and RH in half can be used to determine the angles between the RT faces.

rt=PolyhedronData["RhombicTriacontahedron","Faces"];
rh=PolyhedronData["RhombicHexecontahedron","Faces"];
rhc=Scale[rh,0.618{1,1,1},{0,0,0}];
p=Polygon[0.8{{-2,-2,0},{2,-2,0},{2,2,0},{-2,2,0}}];
Graphics3D[{Rotate[Rotate[{{Yellow,rhc}, Opacity[0.7],rt},β,{0,1,0}],(Pi/2-ArcTan[0.618^2]),{0,1,0}],Green,p},SphericalRegion->True,Boxed->False,ViewPoint->{2,10,4},ViewAngle->0.11]

Here are the definitions used in the constructions.

rtn=Rotate[rt,2Pi/10,{0,0,1}];
rhn=Rotate[rh,2Pi/10,{0,0,1}];
ico=PolyhedronData["Icosahedron","Faces"];
icov=PolyhedronData["Icosahedron","VertexCoordinates"];
tico=PolyhedronData["TruncatedIcosahedron","Faces"];
icon=Scale[ico,2 Sin[α]{1,1,1},{0,0,0}];
dod=PolyhedronData["Dodecahedron","Faces"];
td=PolyhedronData["TruncatedDodecahedron","Faces"];
dodn=Scale[dod,2 Cos[α]{1,1,1},{0,0,0}];
dodv=PolyhedronData["Dodecahedron","VertexCoordinates"];
id=PolyhedronData["Icosidodecahedron","Faces"];

Icosahedron (ICO)

The icosahedron (ICO) is one of the five Platonic solids.

Graphics3D[ico,Boxed->False]

Twelve RTs placed at the vertices of the icosahedron enclose an RH. Such RT clusters appear in photos of certain quasicrystals.

rtico=Map[Translate[rtn,#]&,fd icov];
Graphics3D[{{Opacity[0.3],rtico},Red,Rotate[rh,Pi,{0,0,1}]},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,100},ViewAngle->0.01]

Here is a cluster of 12 RHs without transparency.

Graphics3D[{rtico},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,100},ViewAngle->0.01]

When dodecahedra are used instead of RTs, they are attached to each other along their edges.

rticodod=Map[Translate[dodn,#]&,fd icov];
Graphics3D[{{rticodod},Red,Rotate[rh,Pi,{0,0,1}]},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,100},ViewAngle->0.01]

Truncated Icosahedron (TICO) (5, 6, 6)

The truncated icosahedron (TICO) is the shape most widely used for a soccer ball. It is also the overall structure of the C60 molecule, Buckminsterfullerene.

Graphics3D[tico,Boxed->False,SphericalRegion->True,Boxed->False,ViewPoint->{0,10,3},ViewAngle->0.1]

ticov=PolyhedronData["TruncatedIcosahedron","VertexCoordinates"];
rttico=Map[Translate[rtn,#]&,fd ticov];
Graphics3D[{rttico,Green,Scale[tico,2.4{1,1,1},{0,0,0}]},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1]

Here ICOs replace RTs; the ICOs meet along their edges.

icotico=Map[Translate[icon,#]&,fd ticov];
Graphics3D[{icotico,Green,Scale[tico,2.4{1,1,1},{0,0,0}]},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1]

Icosidodecahedron (ID) (3, 5, 3, 5)

The icosidodecahedron (ID) can be constructed as a truncation of either an icosahedron or a dodecahedron.

Graphics3D[id,Boxed->False]

Here is the corresponding cluster.

idv=PolyhedronData["Icosidodecahedron","VertexCoordinates"];
rtid=Map[Translate[rt,#]&,fd idv];
Graphics3D[{RGBColor[0,1,1],rtid},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1]

Let us add 12 RTs at the vertices of the ICO.

rtico1=Map[Translate[rtn,#]&,(ϕ^2+fd) icov];
Graphics3D[{{RGBColor[0,1,1],rtid},Yellow,Rotate[rtico1,Pi,{0,0,1}]},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1,PlotRange->{{-7,7},{-7,7},{-7,7}}]

Now add 12 RHs at the vertices of the DOD.

rhicotip=Map[Translate[rhn,#]&,ϕ fd dodv];
Graphics3D[{Specularity[0.3],RGBColor[1,0.4,0.3],Rotate[rhicotip,Pi,{0,0,1}],{RGBColor[0,1,1],rtid},Yellow,Rotate[rtico1,Pi,{0,0,1}]},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1]

Add some more RTs at the vertices of an ID. This construction can be continued by adding more RTs and RHs.

rtid1=Map[Translate[rt,#]&,ϕ fd idv];
Graphics3D[{rtid1,RGBColor[1,0.4,0.3],Rotate[rhicotip,Pi,{0,0,1}],{RGBColor[0,1,1],rtid},Yellow,Rotate[rtico1,Pi,{0,0,1}]},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1]

Truncated Dodecahedron (TD) (3, 10, 10)

This is a special case of dodecahedron truncation, when the edge length is uniform.

Graphics3D[td,Boxed->False]

This cluster of 60 RTs can be interpreted as being assembled from 20 sets of three RTs.

tdv=PolyhedronData["TruncatedDodecahedron","VertexCoordinates"];
rttd=Map[Translate[rt,#]&,fd tdv];
Graphics3D[{rttd},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1]

Dodecahedron (DOD) (5, 5, 5)

The usual pentagonal dodecahedron is one of the five Platonic solids.

Graphics3D[dod,Boxed->False]

Here is its associated cluster.

dodv=PolyhedronData["Dodecahedron","VertexCoordinates"];
rtdod=Map[Translate[rtn,#]&,fd dodv];
Graphics3D[{Yellow,rtdod},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1]

This investigates how the basic polyhedron relates to its associated cluster.

Manipulate[
Graphics3D[{Scale[dod,en{1,1,1},{0,0,0}],Yellow,rtdod},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1],{{en,3.7,"enlarge"},1,5},TrackedSymbols->en, SaveDefinitions->True]

The cluster of 20 RTs can be fitted with 12 RHs placed at the vertices of an ICO.

rhico=Map[Translate[rhn,#]&,ϕ fd icov];
Graphics3D[{{Yellow,rtdod},RGBColor[0,0.7,1],rhico},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1]

Great Rhombicosidodecahedron (GRID) (4, 6, 10)

This is a beautiful shape. Somewhat similar shapes can be seen in some photographs of quasicrystals.

grid=PolyhedronData["GreatRhombicosidodecahedron","Faces"];
Graphics3D[grid, SphericalRegion->True,Boxed->False,ViewPoint->{-4,10,5},ViewAngle->0.1]

Here is its associated cluster.

gridv=PolyhedronData["GreatRhombicosidodecahedron","VertexCoordinates"];
rta=Rotate[rt,β,{0,1,0}];
rtgrid=Map[Translate[rta,#]&,fd gridv];
Graphics3D[{rtgrid,Yellow,Scale[grid,2.3{1,1,1},{0,0,0}]},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1]

Small Rhombicosidodecahedron (SRID) (3, 4, 5, 4)

An SRID has 60 vertices. In the related cluster, each RT is connected to four adjacent RTs, as opposed to the TICO-based cluster, where each RT is connected to only three adjacent RTs.

srid=PolyhedronData["SmallRhombicosidodecahedron","Faces"];
Graphics3D[srid, SphericalRegion->True,Boxed->False,ViewPoint->{-4,10,5},ViewAngle->0.1]

Here is its associated cluster.

sridv=PolyhedronData["SmallRhombicosidodecahedron","VertexCoordinates"];
rta=Rotate[rt,β,{0,1,0}];
rtsrid=Map[Translate[rta,#]&,fd sridv];
Graphics3D[{rtsrid,Green,Scale[srid,2.3{1,1,1},{0,0,0}]},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1]

This cluster can also be extended by adding RHs, for example at the vertices of an ICO.

rhico1=Map[Translate[rhn,#]&,ϕ^2 fd icov];
Graphics3D[{rtsrid,RGBColor[0,1,0.5],Rotate[rhico1,-β,{0,1,0}]},SphericalRegion->True,Boxed->False,ViewPoint->{10,0,3},ViewAngle->0.1]

Summary of Truncations and Their Clusters

Here is a summary of the clusters that correspond to the various truncations.

Row[Graphics3D[#,Boxed->False,ImageSize->200]&/@{ico,rtico}]

Row[Graphics3D[#,Boxed->False,ImageSize->200]&/@{tico,rttico}]

Row[Graphics3D[#,Boxed->False,ImageSize->200]&/@{id,rtid}]

Row[Graphics3D[#,Boxed->False,ImageSize->200]&/@{td,rttd}]

Row[Graphics3D[#,Boxed->False,ImageSize->200]&/@{dod,rtdod}]

Row[Graphics3D[#,Boxed->False,ImageSize->200]&/@{grid,rtgrid}]

Row[Graphics3D[#,Boxed->False,ImageSize->200]&/@{srid,rtsrid}]

Cube (4, 4, 4)

The cube is one of the five Platonic solids.

Graphics3D[cub, SphericalRegion->True,Boxed->False,ViewPoint->{-4,10,5},ViewAngle->0.15]

Here is its associated cluster.

cubv=PolyhedronData["Cube","VertexCoordinates"];
rtcub=Map[Translate[rta,#]&, 2.7527 cubv];
Graphics3D[{rtcub},SphericalRegion->True,Boxed->False,ViewPoint->{-4,10,5},ViewAngle->0.1]

Two Johnson Solids

A number of Johnson solids can be considered as parts of the above polyhedra. The two shown here could be used as structures.

pgc=PolyhedronData["PentagonalGyrobicupola","Faces"];
mdi=PolyhedronData["MetabidiminishedIcosahedron","Faces"];
Graphics3D[pgc,Boxed->False]

Graphics3D[mdi,Boxed->False]

Here are their clusters.

pgcv=PolyhedronData["PentagonalGyrobicupola","VertexCoordinates"];
rtpgc=Map[Translate[rt,#]&,fd pgcv];
Graphics3D[{rtpgc},SphericalRegion->True,Boxed->False,ViewPoint->{0,10,6},ViewAngle->0.1]

mdiv=PolyhedronData["MetabidiminishedIcosahedron","VertexCoordinates"];
rtmdi=Map[Translate[rta,#]&,fd mdiv];
Graphics3D[{rtmdi},SphericalRegion->True,Boxed->False,ViewPoint->{0,10,0},ViewAngle->0.1]

Connections with Vertices

Interesting clusters can also be produced when the RTs meet at their vertices. For instance, RTs at RT vertices meet with their fivefold tips.

rtv=PolyhedronData["RhombicTriacontahedron","VertexCoordinates"];
rtrt=Map[Translate[rt,#]&,d5 rtv];
rtbig=Scale[rt, 1.535fd{1,1,1},{0,0,0}];
Graphics3D[{rtrt,{Yellow,Opacity[0.7],rtbig},Green,Scale[rt,3.26{1,1,1},{0,0,0}]},SphericalRegion->True,Boxed->False,ViewPoint->{0,0,10},ViewAngle->0.1]

RTs at the vertices of a rhombic dodecahedron (RD) meet with their threefold tips. Adjacent pairs of RTs overlap in a flat golden rhombohedron, creating another closed structure.

Manipulate[
Graphics3D[{Map[Translate[rtb,#]&,m d3 rdv],rd},SphericalRegion->True,Boxed->False,ViewPoint->{0,10,0},ViewAngle->0.1],
{{m,1,"close"},1,0.812},TrackedSymbols:>m,SaveDefinitions->True,
Initialization->(
ϕ=GoldenRatio;
α=ArcTan[ϕ];
β=ArcTan[1/ϕ];
ce=N[2Sin[α]];
d3=ce Sqrt[3];
rt=PolyhedronData["RhombicTriacontahedron","Faces"];
rtb=Rotate[Rotate[rt,β,{0,1,0}],Pi/4,{0,0,1}];
rdv=PolyhedronData["RhombicDodecahedron","VertexCoordinates"];
rd=PolyhedronData["RhombicDodecahedron","Faces"];
)]

References

Sz. Bérczi, “From the Periodic System of Platonic and Archimedean Solids and Tessellations to the 4D Regular Polyhedra and Tessellations (with Extensions to Some 5D Polytopes),” Symmetry: Culture and Science, 11(1–4), 2003 pp. 125–137.

S. Kabai. “21609 Clusters of Polyhedra” from the Wolfram Demonstrations Project—A Wolfram Web Resource. www.demonstrations.wolfram.com/21609ClustersOfPolyhedra.

G. Gévay, “Icosahedral Morphology,” Fivefold Symmetry (I. Hargitai, ed.), Singapore: World Scientific, 1992.

Image Reference:

Sz. Bérczi, “A szabályos és féligszabályos (platoni és archimedészi) testek és mozaikok periódusos rendszere,” Középiskolai Matematikai Lapok, 59(5), 1979 pp. 193–199.