Use of Padé Approximants to Estimate the Rayleigh Wave Speed

A. T. Spathis

There exists a range of explicit and approximate solutions to the cubic polynomial Rayleigh equation for the speed of surface waves across an elastic half-space. This article presents an alternative approach that uses Padé approximants to estimate the Rayleigh wave speed with five different approximations derived for two expansions about different points. Maximum relative absolute errors of between 0.34% and 0.00011% occur for the full range of the Poisson ratio from -1 to 0.5. Even smaller errors occur when the Poisson ratio is restricted within a range of 0 to 0.5. For higher-order approximants, the derived expressions for the Rayleigh wave speed are more accurate than previously published solutions, but incur a slight cost in extra arithmetic operations, depending on the desired accuracy.

Introduction

In 1885 Lord Rayleigh published his paper “On Waves Propagated along the Plane Surface of an Elastic Solid” [] and observed that:

It is proposed to investigate the behavior of waves upon the plane surface of an infinite homogeneous isotropic elastic solid, their character being such that the disturbance is confined to a superficial region, of thickness comparable with the wave-length. ... It is not improbable that the surface waves here investigated play an important part in earthquakes, and in the collision of elastic solids. Diverging in two dimensions only, they must acquire at a great distance from the source a continually increasing preponderance.

The italicized phrase above is a supreme understatement, given the ensuing history of seismology. In any case, Rayleigh proved the theoretical existence of surface waves on an elastic half-space and showed that the speed of such waves may be calculated from the real roots of a cubic polynomial whose coefficients are all real and depend on the ratio of the S-wave velocity to the P-wave velocity, or alternatively on the Poisson ratio ν of the elastic half-space. He provides the solutions for harmonic waves for both incompressible and compressible half-spaces, shows the elliptic orbit of points on the surface as the wave travels across the surface, demonstrates that the motion is restricted to within approximately one wavelength of the surface, and states that the Poisson ratio may lie between 0.5 and -1 for an elastic material. However, he does not provide explicit expressions for the Rayleigh wave speed.

It appears that the first paper that published explicit expressions for the Rayleigh wave speed for the full range of elastic material properties was by Rahman and Barber []. Since that time, a number of authors have sought to develop alternative analytical expressions for the Rayleigh wave speed [–]. It is noted that the solutions provided cannot be used indiscriminately, as care is required on occasions to choose the correct root to ensure a smooth and continuous estimate of the Rayleigh wave speed [, , ]. A parallel effort has attempted to derive approximate expressions for the Rayleigh wave speed [, –].

Complete analytical derivations were provided by [, , , , ]. Others have used computer algebra to assist in their derivations [, , ]. The original approach given in [] contains unspecified typographical errors [, ]. Indeed, the recent solution given in [] appears to have been derived earlier and independently but with typographical errors []. It has also been shown to be identical to the solution provided in []. Cardano’s formula for the roots of a cubic polynomial with real coefficients [, ] is used by [, , , , ], although the starting point in [] appears to be different from the other solutions. A more recent solution appears to use Cardano’s formula (but referred to as Shengjin’s formula) []. As an aside, an interesting history of Cardano’s formula appears in [].

Cardano’s formula was published in 1545, and it is perhaps surprising that no explicit solution for the Rayleigh speed was available until the Rahman and Barber publication []. It would appear unreasonable to expect that Rayleigh was not aware of the Cardano formula. In any case, and as just one example of prior publication of the Rayleigh wave speed, we may refer to the work in J. E. White’s book, Underground Sound []. Given without derivation, and in somewhat standard notation often associated with the use of Cardano’s formula, we find by simple algebra that White’s solution is identical to that of Rahman and Barber. It may be speculated that similar solutions were found even earlier.

The approximate expressions for the Rayleigh wave speed of surface waves have been derived by various methods, including Taylor series expansion of the Rayleigh equation [], approximation of the Rayleigh equation to lower-degree polynomials using the Lanczos method [], minimization of the integral of the Rayleigh equation with arbitrary coefficients using a least-squares approach [], least-squares minimization [, ] given a known exact solution [, ], use of a bilinear function for the root and applying least squares to determine the coefficients of the bilinear function [], and an iterative method with asymptotic quadratic convergence [].

In this article, we follow the approach given by Liner [], but rather than using a Taylor series expansion of the Rayleigh equation, we use Padé approximants. Padé approximants of various orders are described and their accuracy compared to the exact solution given in []. The complexity of the various derived solutions is assessed in terms of the number of numerical operations required to calculate the Rayleigh wave speed.

Method of Approximation

Functions may be approximated in various ways. Perhaps the best known is the Taylor series expansion, whereby a function f(z) can be expressed as an infinite series expanded around the point a as

f(z)=(∑_(k=0)^∞)(((f^k)(a))/(k!))(((z-a))^k),

where (f^k)(a) is the (k^th) derivative of the function evaluated at the point a. It is usual to truncate the series to use the lower-order terms as an approximation to the function.

An alternative method to approximate a function is to use Padé approximants. Here the function is approximated as a rational function of two truncated polynomials expanded around the point a:

R(z)=(((Underoverscript[∑ , (i=0), m]) (((Subscript[c, i])(z-a))^i))/((Underoverscript[∑ , (j=0), n]) (((Subscript[d, j])(z-a))^j))),

where the numerator and denominator are polynomials of degree at most m and at most n, respectively. The approximant is referred to as a Padé approximant of type (m,n). The approximation given in equation () has m+n+1 parameters.

The Rayleigh equation [] for an elastic half-space is given by

(s^3)-8(s^2)+(24-16Λ)s-16(1-Λ)=0,

where s =(Subscript[c, R]^2)/(β^2), Λ=(β^2)/(α^2), (Subscript[c, R]) is the Rayleigh wave speed, and α and β are the P-wave and S-wave velocities of the medium, respectively. Real roots of equation () represent the normalized Rayleigh wave speed, and in the case of several real roots, the smallest is taken. The Poisson ratio may be calculated to give ν=(1-2Λ)/(2-2Λ).

The Padé approximant is found for the left-hand side of equation (), using computer algebra to calculate the necessary coefficients []. Equating the numerator polynomial in equation () to zero yields the estimate of the normalized Rayleigh speed. Multiple solutions are possible, and these depend on the Padé approximant type, (m,n). Given that the Rayleigh equation is a cubic polynomial, the approximations are restricted to m≤2 and n≤3. In particular, the following Padé approximant types are examined: (1,1), (1,2), (1,3), (2,2), and (2,3).

Results

The five sets of Padé approximants obtained yield solutions for the value of s in equation () with the following forms: for types (1,1), (1,2), and (1,3), the solutions are ratios of polynomials in Λ of degree 2, 3, and 4, respectively. In each case, both the numerator and denominator polynomials have identical degree, and a general expression for them is

s=(((Underoverscript[∑ , (k=0), (n+1)]) (Subscript[h, k])(Λ^k))/((Underoverscript[∑ , (k=0), (n+1)]) (Subscript[g, k])(Λ^k)))

for the type (1,n). For the types (2,2), and (2,3), the general expression is

s=(((Underoverscript[∑ , (k=0), 2]) (Subscript[h, k])(Λ^k)+A(Sqrt[(Underoverscript[∑ , (k=0), 4]) (Subscript[p, k])(Λ^k)]))/((Underoverscript[∑ , (k=0), r]) (Subscript[g, k])(Λ^k))),

where r=1 for type (2,2) and r=2 for type (2,3). The coefficient A=-1 for all cases considered here, except in the single case of type (2,2) for expansion about 1/(Sqrt[3]), in which case A=1.

Like the Taylor series expansion, the Padé approximants are expansions about a given value. In the first instance, expansions were obtained around unity, following previous work [], but after some trial and error, expansions around 1/(Sqrt[3])were found to be superior in terms of minimizing the absolute relative error across the full range of values for Λ. It is worth repeating that the expansions are done for the ratio of the Rayleigh wave speed to the S-wave velocity squared s, unlike the Taylor expansion in Liner [] that is done about the square root of s. Clearly, it is possible to seek the value around which expansions are minimized using a least-squares approach, some aspects of which are discussed below. Below are shown the results obtained for the coefficients in () and () for expansions about 1/(Sqrt[3]) (suitable for the full range of Poisson’s ratio) and 9/11 (suitable for non-negative Poisson’s ratio), respectively. The coefficient values were obtained using Mathematica 9 and are exact.

The relative absolute errors in percentages for the range of Λ are shown below for some of the cases considered. The errors are defined as

Δ=100|(((Subscript[c, (Subscript[R, n])])-(Subscript[c, (Subscript[R, a])]))/(Subscript[c, (Subscript[R, a])]))|,

where (Subscript[R, n]) and (Subscript[R, a]) denote numerical and analytical solutions for the Rayleigh wave speed, respectively, and the analytical solution refers to that in [].

Figure  shows a comparison of the exact analytical solution [], the solution obtained using the Padé approximant (1,1), and the solution for a Taylor expansion of the Rayleigh equation given in equation (). The solution based on the Padé approximant was for an expansion with a=1/(Sqrt[3]), while the Taylor series solution was for an expansion with a=1. The relative absolute errors for these two approximate solutions and the one provided by Liner [] are shown in Figure . The Liner solution was a Taylor series expansion in the normalized Rayleigh wave speed, whereas the expansion in its square is shown in Figure  and labeled as “Taylor.” It is clear that both Taylor series expansions have increasing errors as Λ=(β^2)/(α^2) increases. The solution based on the Padé approximant (1,1) has larger errors than either of the Taylor expansion solutions for smaller values of Λ but performs better for larger values of Λ.

Figures  and  show the relative absolute errors for solutions based on the Padé approximants (1,2), (1,3) and (2,2), (2,3) expanded around the point a=1/(Sqrt[3]). As expected, the errors are smaller for the solutions based on higher-order Padé approximants.

The following function gives an exact analytical expression for the Rayleigh wave speed [, ].

vinhR[Λ_]:=Module[
{R,D},
R=2(27-90Λ+99Λ^2-32Λ^3)/27;
D=4(1-Λ)^2(11-62Λ+107Λ^2-64Λ^3)/27;
Sqrt[4(1-Λ)(2-4 Λ/3+(R+Sqrt[D])^(1/3)+(R-Sqrt[D])^(1/3))^(-1)]
]

The function taylorR gives the Taylor series expansion in the square of the ratio of Rayleigh wave velocity to the S-wave velocity. (The expansion is not in the ratio alone as in the Liner Taylor series expansion given below.)

taylorR[Λ_]:=Sqrt[(21-16 Λ-Sqrt[141-352 Λ+256 Λ^2])/10]

The function padeR calculates the Rayleigh wave speed based on using Padé approximants. Here mdegree is the numerator degree, ndegree is the denominator degree, avalue is the expansion point, and root1or2 is 1 or 2, so as to ensure the smallest root is chosen. (Normally root1or2 is 1, and an incorrect choice is obvious when overlaying the Rayleigh velocity estimate and the exact analytical Rayleigh wave velocity.)

padeR[Λ_,mdegree_,ndegree_,avalue_,root1or2_]:=Module[
{padeExpansion,m},
padeExpansion=PadeApproximant[m^3-8 m^2+(24-16 Λ) m-16(1-Λ),{m,avalue,{mdegree,ndegree}}];
Sqrt[m/.Solve[Numerator[padeExpansion]==0,m][[root1or2]]]
]

The function legName is for the labels in the legend of some of the plots. rspeed is used to switch to one of the functions defined for the Rayleigh wave speed; they are defined in the body of the article or in the Appendix.

legName[rspeed_]:=Switch[rspeed,
linerR,"Liner",
taylorR,"Taylor",
vinhR,"analytical",
bergmannR,"Bergmann",
rahMR,"Rahman and Michelitsch",
liRall,"Li full range Poisson ratio",
liRpos,"Li positive Poisson ratio",
vinhMR2,Row[{"Vinh and Malischewsky to order ",(ν^2)}],
vinhMR3,Row[{"Vinh and Malischewsky to order ",(ν^3)}],
vinhMR4,Row[{"Vinh and Malischewsky to order ",(ν^4)}]]

plotRayleighSpeedEstimate is a plotting function that enables comparison of the Rayleigh wave speed obtained by using two functions given in either the body of the report or in the Appendix, and also one derived from a Padé approximant (see the function legName). The input parameters are rspeed1, rspeed2 (for the two different functions), and the Padé approximant parameters. Λmax is 3/4 for the full range of Poisson’s ratio and 1/2 for positive Poisson’s ratio. Note that when Λ=0, ν=1/2; Λ=1/2, ν=0; Λ=3/4, ν=–1.

plotRayleighSpeedEstimate[rspeed1_,rspeed2_,mdegree_,ndegree_,avalue_,root1or2_,Λmax_]:=
Plot[
{
rspeed1[x],
rspeed2[x],
padeR[x,mdegree,ndegree,avalue,root1or2]
},
{x,0,Λmax},
ImageSize->Scaled[0.7],
Frame->True,
FrameLabel->{Λ,((Subscript[C, R])/β)},
BaseStyle->{FontSize->12},
GridLines->Automatic,
GridLinesStyle->Directive[{Dotted}],PlotStyle->{{Dashing[{}],Black},{Dashed,Blue},{Dashed,Red}},
PlotLegends->LineLegend[
{Black,{Dashed,Blue},{Dashed,Red}},
{
legName[rspeed1],legName[rspeed2],
Row[{"Padé (",mdegree,", ",ndegree,"), \n",Style["a",Italic]," = ",TraditionalForm[avalue]}]
},
LabelStyle->{12}
]
]

plotRayleighSpeedEstimate[vinhR,taylorR,1,1,1/Sqrt[3],1,3/4]

We define a function for the approximation to the Rayleigh wave speed given by Liner []. The approximation is based on a Taylor series expansion in the ratio of the Rayleigh wave speed to the shear wave speed.

linerR[Λ_]:=(20-Sqrt[256Λ^2-336 Λ+130])/(16Λ+9)

plot3RayleighWaveSpeedRelativeError is a plotting function for comparing the relative absolute errors for the Rayleigh speed estimates from two functions and an estimate obtained from a Padé approximant with similar inputs, described above. ymax is the maximum range for the relative error and is adjusted to scale the plot.

plot3RayleighWaveSpeedRelativeError[rspeed1_,rspeed2_,m1_,n1_,a1_,root1or2_,ymax_,Λmax_]:=Module[
{padeR1},
padeR1=padeR[Λ,m1,n1,a1,root1or2];
Plot[
{
100 Abs[(rspeed1[Λ]-vinhR[Λ])/vinhR[Λ]],
100 Abs[(rspeed2[Λ]-vinhR[Λ])/vinhR[Λ]],
100 Abs[(padeR1-vinhR[Λ])/vinhR[Λ]]
},
{Λ,0,Λmax},
ImageSize->Scaled[0.7],
PlotRange->{0,ymax},
Frame->True,
FrameLabel->{Λ,"Relative Absolute Error (%)"},
BaseStyle->{FontSize->12},
GridLines->Automatic,
GridLinesStyle->Directive[{Dotted}],
PlotStyle->{{Dashing[{}],Black},{Dashed,Blue},{Dashed,Red}},
PlotLegends->LineLegend[{Black,{Dashed,Blue},{Dashed,Red}},{legName[rspeed1],legName[rspeed2],Row[{"Padé (",m1,", ",n1,"), \n",Style["a",Italic]," = ",TraditionalForm[a1]}]},
LabelStyle->{12}]
]
]

plot3RayleighWaveSpeedRelativeError[linerR,taylorR,1,1,1/Sqrt[3],1,0.5,3/4]

plot2RayleighWaveSpeedRelativeError is a plotting function for comparing the relative absolute errors for the Rayleigh speed estimates obtained using two Padé approximants. The function has similar inputs described above, and here the suffix 1 or 2 refers to the given Padé approximant.

plot2RayleighWaveSpeedRelativeError[m1_,n1_,a1_,root1or21_,m2_,n2_,a2_,root1or22_,ymax_,Λmax_]:=Module[
{padeR1,padeR2},
padeR1=padeR[Λ,m1,n1,a1,root1or21];
padeR2=padeR[Λ,m2,n2,a2,root1or22];
Plot[
{
100 Abs[(padeR1-vinhR[Λ])/vinhR[Λ]],
100 Abs[(padeR2-vinhR[Λ])/vinhR[Λ]]
},
{Λ,0,Λmax},
ImageSize->Scaled[0.7],
PlotRange->{0,ymax},
Frame->True,
FrameLabel->{"Λ","Relative Absolute Error (%)"},
BaseStyle->{FontSize->12},
GridLines->Automatic,
GridLinesStyle->Directive[{Dotted}],
PlotStyle->{{Dashing[{}],Black},{Dashed,Blue},{Dotted,Red}},
PlotLegends->LineLegend[
{Black,{Dashed,Blue},{Dotted,Red}},
{
Row[{"Padé (",m1,", ",n1,"), \n",Style["a",Italic]," = ",TraditionalForm[a1]}],
Row[{"Padé (",m2,", ",n2,"), \n",Style["a",Italic]," = ",TraditionalForm[a2]}]
},
LabelStyle->{12}
]
]
]

plot2RayleighWaveSpeedRelativeError[1,2,1/Sqrt[3],1,1,3,1/Sqrt[3],1,0.05,3/4]

plot2RayleighWaveSpeedRelativeError[2,2,1/Sqrt[3],2,2,3,1/Sqrt[3],1,0.001,3/4]

It is possible to generate the expressions for equations () and () based on a Padé approximant simply by squaring the Rayleigh wave speed estimate. The square roots of the full set of results given below are good estimates of the Rayleigh wave speed for different ranges of the Poisson ratio. Simple arithmetic yields the results in the forms given in equations () and ().

Here are some useful and accurate expressions for the Rayleigh wave speed squared over the full range of the Poisson ratio with a=1/(Sqrt[3]).

padeR[Λ,1,1,1/Sqrt[3],1]^2

padeR[Λ,1,2,1/Sqrt[3],1]^2

padeR[Λ,1,3,1/Sqrt[3],1]^2

padeR[Λ,2,2,1/Sqrt[3],2]^2 (* note the use of the second root *)

padeR[Λ,2,3,1/Sqrt[3],1]^2

Here are some useful and accurate expressions for the Rayleigh wave speed squared over the positive range of Poisson’s ratio with a=9/11.

padeR[Λ,1,1,9/11,1]^2

padeR[Λ,1,2,9/11,1]^2

padeR[Λ,1,3,9/11,1]^2

padeR[Λ,2,2,9/11,1]^2

padeR[Λ,2,3,9/11,1]^2

Discussion

Polynomial expressions for the Rayleigh wave speed are given in equations () and () with respective coefficients given above. These expressions have been derived using Padé approximants around a=1/(Sqrt[3]) and a=9/11 for 0≤Λ≤0.75 (Poisson ratio in the range 0.5 to -1) and 0≤Λ≤0.5 (Poisson ratio in the range 0.5 to 0), respectively. The two expansion values (a in equations () and ()) were obtained by examining the area under the relative absolute error curve for increments of a between 0.5 and 1. In principle, a least-squares solution for the value of a producing the minimum error would be feasible for each Padé type, but in so doing we ignore the detailed shape of the error curve across the range of Λ values. For example, Figure  shows the relative absolute error for the Rayleigh wave speed based on Padé type (1,2) for expansions around a=1/(Sqrt[3]) and a=2/3. While the error is less for the expansion around a=2/3 for most of the range of Λ values, we observe that for larger values of Λ, the errors become larger and exceed those for the expansion around a=1/(Sqrt[3]). This basic behavior is characteristic of the errors obtained (but not shown) using the Padé types (1,1) and (1,3). It is worth noting that for non-negative Poisson’s ratio of 0≤Λ≤0.5, the errors are smaller for expansions about a=2/3 for the three Padé types (1,1), (1,2), and (1,3). The question arises, is it possible to expand around another value that will have smaller errors for non-negative Poisson’s ratio? Figure  shows the relative absolute error for the Padé type (1,2) expanded about a=2/3 and a=7/8. The error in the latter case is smaller for all values up to approximately Λ≃0 .47, after which it increases beyond that for the expansion about a=2/3, but not significantly. The maximum error is about the same for both cases. Once more, similar behavior is observed for the other two Padé types (1,1) and (1,3).

Figure  shows the relative absolute errors for the Rayleigh wave speed based on using the Padé type (2,3) expanded around a=1/(Sqrt[3]) and a=2/3. The behavior of these curves is different from those shown earlier—here there is a monotonic decrease in the error for most of the full range of Λ as it increases. The errors are one hundred times smaller than those based on the Padé type (1,2) shown in Figure . A somewhat extraordinary reduction of a further five times (so a total of a 500-fold reduction) in relative absolute error occurs for the Rayleigh wave speed estimate based on the Padé type (2,3) expanded around a=9/11 and shown in Figure .

plot2RayleighWaveSpeedRelativeError[1,2,1/Sqrt[3],1,1,2,2/3,1,0.05,3/4]

plot2RayleighWaveSpeedRelativeError[1,2,2/3,1,1,2,7/8,1,0.02,1/2]

plot2RayleighWaveSpeedRelativeError[2,3,1/Sqrt[3],1,2,3,2/3,1,0.0002,3/4]

plot1RayleighWaveSpeedRelativeError is a plotting function for the relative absolute error of the Rayleigh speed obtained using a single Padé approximant. The function has similar inputs described earlier.

plot1RayleighWaveSpeedRelativeError[m1_,n1_,a1_,root1or2_,ymax_,Λmax_]:=Module[
{padeR1},
padeR1=padeR[Λ,m1,n1,a1,root1or2];
Plot[
100 Abs[(padeR1-vinhR[Λ])/vinhR[Λ]],
{Λ,0,Λmax},
ImageSize->Scaled[0.7],
PlotRange->{0,ymax},
Frame->True,
FrameLabel->{Λ,"Relative Absolute Error (%)"},
BaseStyle->{FontSize->12},
GridLines->Automatic,
GridLinesStyle->Directive[{Dotted}],PlotStyle->{{Dashing[{}],Black},{Dashed,Blue},{Dotted,Red}},
PlotLegends->LineLegend[
{Black,{Dashed,Blue},{Dotted,Red}},
{Row[{"Padé (",m1,", ",n1,"), \n",Style["a",Italic]," = ",TraditionalForm[a1]}]},
LabelStyle->{12}
]
]
]

plot1RayleighWaveSpeedRelativeError[2,3,9/11,1,0.00000012,1/2]

It is worth summarizing the various error estimates arising from the Rayleigh wave speed based on the Padé approximant types studied for the two ranges of Poisson’s ratios (Table ). These are compared to other published estimates given in Table . Tables  and  show this data and also the number of arithmetic operations required to compute the value of s (equation ()), from which we estimate any given Rayleigh wave speed. The latter information shows the tradeoff between the accuracy of the Rayleigh wave speed estimate and the associated computational effort. The operations included are addition, subtraction, multiplication, division, and the taking of a root or a trigonometric function; raising to a power is taken as a series of multiplications, and the minimum number of such operations is used wherever possible. It is assumed that an analytical solution is exact, that Λ is known, and that for each approximate solution all coefficients are known and retained as integers until the calculation commences. In the case of the exact solution based on Cardano’s formula, two different expressions exist for different values of Λ, and in this case, the number of operations is given for each path separated by a forward slash. Functions not previously introduced in the body of the text and required to calculate the estimates in Table  may be found in the Appendix.

The data in Tables  and  shows that the computational effort is generally greatest for the three analytical solutions. The approximate solutions based on the Padé approximants improve their error estimates approximately tenfold as we move from Padé types (1,1) to (2,3) for expansions around a=1/(Sqrt[3]). The number of arithmetic operations increases by about five for Padé types (1,1) to (1,3), without a significant change in the number of operations as we move to Padé types (2,2) and (2,3). For the Padé types expanded around a=9/11 and for non-negative Poisson’s ratio, we find a remarkable reduction in the errors, commencing with a thirtyfold reduction in the Padé type (1,1), followed by a twentyfold reduction as we move from Padé types (1,1) to (1,3), and a further tenfold reduction in the errors as we move to Padé types (2,2) to (2,3). The Padé type (1,1) expanded around a=9/11 has a fifteenfold smaller error than either of the Taylor expansions, and with fewer operations. The methods based on least-squares solutions that minimize the area under the absolute error curves perform strongly, with a good mix of relatively small errors and a small number of arithmetic operations. It is necessary to go to the approximation based on Padé type (1,3) before the error is less than that for the solutions based on least squares, but this requires more arithmetic operations.

Conclusion

The Rayleigh wave speed was estimated based on expansions of the Rayleigh equation by Padé approximants and equating the numerator of that representation to zero. The numerator polynomials were solved for the normalized Rayleigh wave speed and provide five distinct solutions. The solutions have varying degrees of accuracy, depending on the value about which the Rayleigh equation is expanded. Good, accurate solutions occur for the full range of Poisson’s ratio, and even more accurate solutions are found for non-negative Poisson’s ratio. It is concluded that these expressions for the Rayleigh wave speed provide a useful approximation, with a balance between accuracy and number of arithmetic operations required.

Appendix

This Appendix contains a number of functions that estimate the Rayleigh wave speed, which may be used to reproduce some results for the approximate solutions found in Table . Other needed functions have been presented in the body of the main text.

Here is the Bergmann formula from Vinh and Malischewsky [].

bergmannR[Λ_]:=Module[
{ν},
ν=(2 Λ-1)/(2 (Λ-1));
(0.87+1.12 ν)/(1+ν)
]

Here is the Vinh and Malischewsky [] formula to degree 2 in Poisson’s ratio.

vinhMR2[Λ_]:=Module[
{ν},
ν=(2 Λ-1)/(2 (Λ-1));
0.8739+0.2008 ν-0.07566 ν^2
]

Here is the Vinh and Malischewsky [] formula to degree 3 in Poisson’s ratio.

vinhMR3[Λ_]:=Module[
{ν},
ν=(2 Λ-1)/(2 (Λ-1));
0.874006+0.19704 ν-0.05558 ν^2-0.02677 ν^3
]

Here is the Vinh and Malischewsky [] formula to degree 4 in Poisson’s ratio.

vinhMR4[Λ_]:=Module[
{ν},
ν=(2 Λ-1)/(2 (Λ-1));
0.8740325+0.1953777 ν-0.038923 ν^2-0.080072 ν^3+0.053299 ν^4
]

Here is the Rahman and Michelitsch [] formula using the Lanczos approximation.

rahMR[Λ_]:=Module[
{ν},
ν=(2 Λ-1)/(2 (Λ-1));
Sqrt[(30.876-14.876 ν - Sqrt[(224.545376 ν^2 -93.122752 ν+124.577376)])/(26 (1-ν))]
]

Here is the Li [] formula for the full range of Poisson’s ratio.

liRall[Λ_]:=Module[
{ν},
ν=(2 Λ-1)/(2 (Λ-1));
Sqrt[(28.84-12.84 ν - Sqrt[(198.89 ν^2 -66.98 ν+124.1)])/(23.18 (1-ν))]
]

Here is the Li [] formula for the positive range of Poisson’s ratio.

liRpos[Λ_]:=Module[
{ν},
ν=(2 Λ-1)/(2 (Λ-1));
Sqrt[(27.425-11.425 ν - Sqrt[(187.4384 ν^2 -52.4769 ν+121.0384)])/(21.5 (1-ν))]
]

References

L. Rayleigh, “On Waves Propagated along the Plane Surface of an Elastic Solid,” Proceedings of the London Mathematical Society, S1-17(1), 1885 pp. 4–11. doi:10.1112/plms/s1-17.1.4.

M. Rahman and J. R. Barber, “Exact Expressions for the Roots of the Secular Equation for Rayleigh Waves,” Journal of Applied Mechanics, 62(1), 1995 pp. 250–252. doi:10.1115/1.2895917.

C. L. Liner, “Rayleigh Wave Approximations,” Journal of Seismic Exploration, 3, 1994 pp. 273–281.

D. Nkemzi, “A New Formula for the Velocity of Rayleigh Waves,” Wave Motion, 26(2), 1997 pp. 199–205. doi:10.1016/S0165-2125(97)00004-8.

P. G. Malischewsky, “Comment to ‘A New Formula for the Velocity of Rayleigh Waves’ by D. Nkemzi [Wave Motion 26 (1997) 199–205],” Wave Motion, 31(1), 2000 pp. 93–96. doi:10.1016/S0165-2125(99)00025-6.

H. Mechkour, “The Exact Expressions for the Roots of Rayleigh Wave Equation,” Proceedings of the 2nd International Colloquium of Mathematics in Engineering and Numerical Physics (MENP-2), Bucharest, 2002, Geometry Balkan Press, 2003 pp. 96–104.

P. C. Vinh and R. W. Ogden, “On Formulas for the Rayleigh Wave Speed,” Wave Motion, 39(3), 2004 pp. 191–197. doi:10.1016/j.wavemoti.2003.08.004.

P. G. Malischewsky Auning, “ A Note on Rayleigh-Wave Velocities as a Function of the Material Parameters,” Geofísica internacional, 43(3), 2004 pp. 507–509. www.geofisica.unam.mx/unid_apoyo/editorial/publicaciones/investigacion/geofisica_internacional/anteriores/2004/03/Malischewsky.pdf.

D. W. Nkemzi, “A Simple and Explicit Algebraic Expression for the Rayleigh Wave Velocity,” Mechanical Research Communications, 35(3), 2008 pp. 201–205. doi:10.1016/j.mechrescom.2007.10.005.

P. G. Malischewsky, “Reply to Nkemzi, D. W., ‘A Simple and Explicit Algebraic Expression for the Rayleigh Wave Velocity,’ [Mechanical Research Communications (2007), doi:10.1016/j.mechrescom.2007.10.005],” Mechanical Research Communications, 35(6), 2008 p. 428. doi:10.1016/j.mechrescom.2008.01.011.

X.-F. Liu and Y.-H. Fan, “A New Formula for the Rayleigh Wave Velocity,” Advanced Materials Research, 452–453, 2012 pp. 233–237.

D. Royer, “A Study of the Secular Equation for Rayleigh Waves Using the Root Locus Method,” Ultrasonics, 39(3), 2001 pp. 223–225. doi:10.1016/S0041-624X(00)00063-9.

M. Rahman and T. Michelitsch, “A Note on the Formula for the Rayleigh Wave Speed,” Wave Motion, 43(3), 2006 pp. 272–276. doi:10.1016/j.wavemoti.2005.10.002.

X.-F. Li, “On Approximate Analytic Expressions for the Velocity of Rayleigh Waves,” Wave Motion, 44(2), 2006 pp. 120–127. doi:10.1016/j.wavemoti.2006.07.003.

P. C. Vinh and P. G. Malischewsky, “Explanation for Malischewsky’s Approximate Expression for the Rayleigh Wave Velocity,” Ultrasonics, 45(1–4), 2006 pp. 77–81. doi:10.1016/j.ultras.2006.07.001.

D. Royer and D. Clorennec, “An Improved Approximation for the Rayleigh Wave Equation,” Ultrasonics, 46(1), 2007 pp. 23–24. doi:10.1016/j.ultras.2006.09.006.

A. V. Pichugin. “Approximation of the Rayleigh Wave Speed.” (Jan 10, 2008) people.brunel.ac.uk/~mastaap/draft06rayleigh.pdf.

P. C. Vinh and P. G. Malischewsky, “Improved Approximations of the Rayleigh Wave Velocity,” Journal of Thermoplastic Composite Materials, 21(4), 2008 pp. 337–352. doi:10.1177/0892705708089479.

M. Abramowitz and I. A. Segun, eds., Handbook of Mathematical Functions, New York: Dover Publications, 1965.

D. Zwillenger, ed., Standard Mathematical Tables and Formulae, 31st ed., Boca Raton: CRC Press, 2003.

P. R. Hewitt. “Cardano’s Formulas or a Pivotal Moment in the History of Algebra.” (Apr 7, 2009) livetoad.org/Courses/Documents/bb63/Notes/cardanos_formulas.pdf.

J. E. White, Underground Sound: Application of Seismic Waves, New York: Elsevier, 1983.

Mathematica, Release Version 9.0, Champaign: Wolfram Research, Inc., 2013.

P. C. Vinh and P. G. Malischewsky, “An Approach for Obtaining Approximate Formulas for the Rayleigh Wave Velocity,” Wave Motion, 44(7–8), 2007 pp. 549–562. doi:10.1016/j.wavemoti.2007.02.001.