Tetrahedra Packing

MonthName Day, Year

Ed Pegg Jr, Scientific Information Group

Back in 325 BC, Aristotle talked about which polyhedra can fill space, and noted that regular tetrahedra could fill space.

Around 1470 AD, Regiomontanus showed that Aristotle was wrong. He also found the spot where a statue on a pedestal appears the largest, as shown in the Demonstration "The Statue of Regiomontanus".

In 1896, Minkowski tried to solve the problem of how well tetrahedra could pack. He failed. But he did introduce many valuable tools to math, such as "The Minkowski Sum of Two Triangles".

In 1900, Hilbert tried the problem of tetrahedra packing and included it as a part of problem 18 in his list of unsolved problems. Hilbert is also famous for the Hilbert curve and "The Hilbert Hotel".

In 1972, Ulam conjectured that spheres had a worse packing density than tetrahedra. He wound up being correct, as we shall see. He is also known for "The Ulam Prime Spiral".

In 2006, Conway and Torquato found a packing density of .7175. Conway is famous for the Schmitt–Conway biprism, "Intrinsically Knotted Graphs", the "Look and Say sequence", and the Game of Life.

In 2008, Chen increased the packing density to .7786. A series of short-lived records were set and published prominently in Nature, Science, and Physical Review Letters, which are the most esteemed scientific journals to publish in. The New York Times reported on the results. All of these results have now been beaten.

As of July 27, 2010, the best-known packing density for the tetrahedron is 4000/4671 = .856347.... It was found by Chen, Engel, and Glotzer. Here's Mathematica code for the 16-tetrahedra cell for this packing.

dimer = {{2,2,2},{2,-1,-1},{-1,2,-1},{-1,-1,2},{-2,-2,-2}};
dimerpolygons = {{1,2,3},{1,2,4},{1,3,4},{2,3,4},{2,3,5},{2,4,5},{3,4,5}};
{a,b,c,d} ={{870,321,-21},{-102,831,405},
{282,-249,741},{38,5,-25}}/320;
dimerpoints[{m_Integer,n_Integer,o_Integer}] := 
If[EvenQ[m+n+o],dimer + Table[{m a + n b + o c}[[1]],{5}],
-dimer + Table[{m a + n b + o c}[[1]] +d,{5}]];

Graphics3D[{Opacity[.8],
Table[Polygon[dimerpoints[{r,s,t}][[#]]]&/@dimerpolygons,{r,0,1},{s,0,1},{t,0,1}]},Boxed-> False,SphericalRegion-> True, Method->{"ShrinkWrap"->True}, ImageSize-> 400]

Here is a larger section of that packing.

Graphics3D[{Opacity[.9],
Table[Polygon[dimerpoints[{r,s,t}][[#]]]&/@dimerpolygons,{r,0,3},{s,0,3},{t,0,3}]},Boxed-> False,SphericalRegion-> True, Method->{"ShrinkWrap"->True}, ImageSize-> 400]

This has been added to the "Densest Tetrahedral Packing" Demonstration.  Here's the best-known packing as seen in the Demonstration.

If tetrahedra aren't regular, there are five known types that will fill space. These are listed in "Space-Filling Tetrahedra". Here is the strangest of them, packed into a triangular prism:

cuberotations= {{{1,0,0},{0,1,0},{0,0,1}},{{0,0,1},{0,-1,0},{1,0,0}},{{0,0,-1},{1,0,0},{0,-1,0}},
{{0,-1,0},{-1,0,0},{0,0,-1}},{{-1,0,0},{0,0,1},{0,1,0}},{{0,1,0},{0,0,-1},{-1,0,0}}};
translations = {{0,0,0},{-1,4,1},{1,6,3},{5,5,4},{4,0,0},{5,1,4}};
Graphics3D[{Opacity[.8],
Polygon/@Subsets[#,{3}]&/@ Table[{{0,3,3},{1,4,2},{3,2,4},{1,0,2}}.cuberotations[[n]] + Table[translations[[n]],{4}],{n,1,6}] },
SphericalRegion-> True, Boxed-> False, Method->{"ShrinkWrap"->True},  ImageSize-> {400,400}]

I glossed over the mistakes made in finding these five polyhedra—three different mathematicians each found four of them. And there might be others, since this is an unsolved question. Even writing this blog entry seems foolhardy, since the best-known result is barely more than a month old. If I am wrong here, I get to join the ranks of 2,500 years worth of famous mathematicians, who were also wrong.  But maybe the problem of tetrahedra packing is finally settled.